dvidrv

[Ivan Kohutek]

Zdravim,

>>neni duvodu proc nepouzit dvi* (kdyz je lepsi).
>O to jsem se pokousel: napsal jsem batch ktery spousti
>dvidrv dvihplj ..., spoustel jsem ho z windows,
>ale z duvodu mne nepochopitelnych jeho beh ztroskota hlaskou
>Warning 1207: cannot open font library file `c:\emtex\fonts\lib300.fli'
>. Kdyz ten samy batch pustim bez windows, probehne tak jak bych si pral.
>Mohl byste mi prosim poradit, jak jste problem tisku pres dvidrv z windows
>vyresil?

Ja spustam z Win95 (konkretne z TexMexu) tiez dosovsky dvidrv,
a to aj na View, aj PreView (LJ II - 300dpi) a aj na tlacenie na LJ (300dpi).
Zatial mi to fungovalo spolahlivo.

Batch pripajam, je mozno kusocek dlhsi, ale ja tam mam aj
'dvi to PS'  a ghostview na prezeranie PS suborov pod DOSom.

****************** zaciatok BATCH

@echo OFF
set MAIN=%1
rem *********************************
rem MAIN je nazov spracovavaneho suboru
rem *********************************
if not exist %MAIN% goto :HELP
if %1==  goto :HELP

rem *********************************
set FONT=%2
rem *********************************
rem FONT= p6l  ihlickova
rem       dj   deskjet
rem       lj   laserjet
rem       ljh  laserjet 600dpi
rem       PS   dvips
rem *********************************
set PORT=%3
rem *********************************
rem PORT=LPT1 LPT2 LPT3 SCR
rem *********************************

if not exist %MAIN% goto :NoMain

set EMTEXDIR=M:\EMTEX
set DVIDRVFONTS=%EMTEXDIR%\fonts
******************************************
set TEXINPUT=%EMTEXDIR%\texinput\latex2e!;%EMTEXDIR%\texinput!;%EMTEXDIR%\dist\latex\packages!
set PATH=%EMTEXDIR%\BIN;%PATH%

if %FONT%==PS goto :PS

if not exist %EMTEXDIR%\bin\dvidrv.exe goto :NoDviDrv

if %PORT%==SCR goto :SCR
if %PORT%==scr goto :SCR
if %PORT%==VIEW goto :VIEW
if %PORT%==view goto :VIEW

goto %FONT%

:p6l
type %EMTEXDIR%\mnu\messprn.txt
dvidrv dvidot p6l @p6l /po=%PORT% /h=12in %MAIN%
goto :END

:dj
type %EMTEXDIR%\mnu\messprn.txt
dvidrv dvihplj +printer-model:deskjet @dj /po=%PORT% %MAIN%

:lj
type %EMTEXDIR%\mnu\messprn.txt
dvidrv dvihplj @lj /po=%PORT% // %MAIN%
goto :END

:ljh
type %EMTEXDIR%\mnu\messprn.txt
dvidrv dvihplj @ljh /og=600 /po=%PORT% /om=2000 %MAIN%
goto :END

:VIEW
dvidrv dviscr @%FONT% %MAIN%
goto :END

:SCR
dvidrv dviscr @%FONT% // %MAIN%
goto :END


:PS
rem set DVIPSVER=dvips16
set DVIPSVER=dvips32
set TEXCONFIG=%EMTEXDIR%\DATA\DVIPS
set GS_LIB=M:\GS\GS3.53

if %PORT%==SCR goto :PSVIEW

if not exist %EMTEXDIR%\bin\%DVIPSVER%.exe goto :NoDvips
if not exist %EMTEXDIR%\bin\dvi-out.exe goto :NoDvi_Out
dvi-out -m %MAIN%
if errorlevel 1 pause
%DVIPSVER% -a %MAIN%
goto :END

:PSVIEW
if not exist %GS_LIB%\gs386.exe goto :NoGS
set DOS4GPATH=M:\GS\OTHERS
%GS_LIB%\gs386.exe -I%GS_LIB%;%GS_LIB%\FONTS %MAIN% > gs.log
goto :END

:NoDvips
echo Program %DVIPSVER%.exe nie je v adresari  %EMTEXDIR%\bin
echo (opravte cesty v subore dvi2xx.bat)
pause
goto :END

:NoDvi_Out
echo Program dvi-out.exe nie je v adresari  %EMTEXDIR%\bin
echo (opravte cesty v subore dvi2xx.bat)
pause
goto :END

:NoDviDrv
echo Program dvidrv.exe nie je v adresari  %EMTEXDIR%\bin
echo (opravte cesty v subore dvi2xx.bat)
pause
goto :END

:NoGS
echo Program gs386.exe nie je v adresari %GS_LIB%
echo (opravte cesty v subore dvi2xx.bat)
pause
goto :END


:NoMain
echo Subor %MAIN% neexistuje.
pause
goto :END

:HELP
echo ************************************
echo syntax : dvi2xx MAIN FONT PORT
echo ************************************
echo MAIN je nazov spracovavaneho suboru
echo ************************************
echo FONT= p6l  ihlickova
echo         dj   deskjet
echo         lj   laserjet
echo         ljh  lserjet 600dpi
echo         PS   dvips
echo ************************************
echo PORT=LPT1 LPT2 LPT3
echo      SCR (monitor, preview)
echo ************************************
goto :END

:END
echo ON