Problem s tiskem

[Peter Bandzuch]

On Fri, 20 Sep 1996, Sibl Bohuslav wrote:

> 
> Dobry den!
> Nainstaloval jsem si na pocitac minitex(PC)
> pouzivam tiskarnu HP DeskJest 520
> v menu pro tisk jsem nastavil:  Print to Laser3
>                                 port:prn
>                                 driver:dvihplj
> 
> Na tiskarne sice neco vyjelo, ale vubec to nevypadalo tak, jak
> ukazovalo Preview. Vyzkousel jsem i mnohe jine nastaveni, ale vzdy to
> byl vysledek jeste horsi. Snazil jsem se objevit nejakou dokumentaci,
> v ktere by byly nejake informaci o tisku, bohuzel jsem vsak take
> neuspel.
> Proto se na vas obracim zda mi muzete doporucit nejakou dokumentaci,
> anebo zda mi muze nekdo primo zdelit, jak resit problem s tiskem.
> Predem dekuji.
> 
> 
  Pouzivam plnu verziu TeX-u a tlaciaren DeskJet 600 a mal som ten
isty problem. Po mensich upravach mi vsak tlac funguje dobre. Tu su 
tri subory, ktore som upravil:

rem   ============================= emtex\mnu\Prints.bat ===================
set MNU=41
if errorlevel 46 goto editCNF
if errorlevel 45 goto reset
set OPT=@%CNF%.cnf
if "%CNF%"=="" set OPT=//
set MARK=%PORT%
if errorlevel 43 set MARK=%MAIN%.%EXT%
if errorlevel 42 goto print
if errorlevel 41 goto preview

:reset
  call %EMTEXDIR%\mnu\tiskarny
  goto end

:preview
  if %OPT%==// type %EMTEXDIR%\mnu\messprn.txt
  dvidrv %SCR% @%LIB%.cnf /pl:$DVIDRVFONTS:%LIB%_{cbas,more} /ps:cs.sub /fl300 %OPT% %MAIN%
  goto end

:print
if %DRIVER%==dvidot  goto dot
if %DRIVER%==dvihplj goto dvihplj
if %DRIVER%==dvips   goto dvips
set MNU=42
goto sorry

:dot
  if not exist %EMTEXDIR%\data\%EXT%.dot goto bsorry
  if %OPT%==// type %EMTEXDIR%\mnu\messprn.txt
  dvidrv dvidot %EXT%.dot @%LIB%.cnf /pl:$DVIDRVFONTS:%LIB%_{cbas,more} /ps:cs.sub %OPT% %MAIN% %MARK%
  goto end

:dvihplj
  if not exist %EMTEXDIR%\bin\dvihplj.exe goto bsorry
  if %OPT%==// type %EMTEXDIR%\mnu\messprn.txt
  if %LIB%==dj call prthpdj.bat %OPT% %MAIN% %MARK%
  if %LIB%==lj call prthplj.bat %OPT% %MAIN% %MARK%
  goto end

:dvips
  if not exist %EMTEXDIR%\bin\dvips.* goto bsorry
  %EMTEXDIR%\bin\dvi-out -m %MAIN%
  if errorlevel 1 pause
  set OPT=
  if "%MARK%"=="%PORT%" set OPT=-o%PORT%
  %EMTEXDIR%\bin\%DVIPSVER% -a -P%LIB% %OPT% %MAIN%
  goto end

:editCNF
  if "%CNF%"=="" echo nejprve vyznacte nazev konfiguracniho souboru (bez pripony cnf)
  if "%CNF%"=="" goto end
  type %EMTEXDIR%\mnu\messprn.txt
  echo zm ‡knˆte jakoukoli kl vesu pro vstup do editoru ...
  %COMSPEC% /c pause > nul
  %EDIT% %CNF%.cnf
  set MNU=41
  goto end

:bsorry
  set MNU=49
:sorry
  %EMTEXDIR%\bin\mnu %EMTEXDIR%\mnu\sorry.mnu
  set MNU=41
:end



rem =========================== emtex\bin\prthpdj.bat
@echo off
dvidrv dvihplj +printer-model:deskjet +left-margin=-3mm +top-margin=-1.5mm @dj /po=prn %1 %2 %3 %4 %5 %6 %7 %8 %9




rem ======================== emtex\mnu\tiskarny.bat
rem ........... Konfigurace tiskaren

rem ....... Nazvy tri zakladnich tiskaren, ktere se objevi v menu.
rem ....... Nazev se nize zopakuje v navesti teto davky.
set PRN1=DeskJet
set PRN2=Matrix
set PRN3=LaserJet

rem ....... Vychozi tiskarna je PRN1:
if "%PRNNAME%"=="" set PRNNAME=%PRN1%

rem ....... Nasleduje konfigurace jednotlivych tiskaren:
rem     PORT   je prn nebo lpt1 nebo lpt2 nebo lpt3
rem     DRIVER je dvidot (pro maticovky) nebo dvihplj (pro laserovky)
rem            nebo dvips (pro PostScriptova vystupni zarizeni)
rem     LIB    je nazev knihovny, ze ktere se ctou bitmapy fontu
rem            p6l je 180dpi, lj je 300dpi a ljh je 600dpi. Dalsi knihovny
rem            jsou tez mozne.
rem     EXT    je nazev pripony souboru, pokud se uzivatel rozhodne
rem            nepouzit tiskarnu, ale vyrobit tiskovy soubor.
rem            Je-li DRIVER=dvidot, ma navic EXT dalsi funkci: urcuje nazev
rem            pouziteho .dot souboru.

goto %PRNNAME%

:Matrix
   set PORT=prn
   set DRIVER=dvidot
   set LIB=fx
   set EXT=fx80
   goto end

:DeskJet
   set PORT=lpt1
   set DRIVER=dvihplj
   set LIB=dj
   set EXT=dhp
   goto end

:LaserJet
   set PORT=
   set DRIVER=dvihplj
   set LIB=lj
   set EXT=lhp
   goto end

rem :PS_Laser
rem    set PORT=lpt3
rem    set DRIVER=dvips
rem    set LIB=ljh
rem    set EXT=ps

:end


  Snad Vam to pomoze.
Pekny den praje,
              Peter Bandzuch

===================================================================
Peter Bandzuch                         e-mail : fyzipban at savba.sk
Institute of Physics,SAS,              phone  : +42 (7) 3782135
Dubravska cesta 9,                     fax    : +42 (7) 376085
84228 Bratislava,
Slovak Republic
===================================================================